MSDynamics.de

Hallo,

Habe eine Spalte in der Tabelle "Sachposten" mit dem Namen "Konto-AZ" also Boolean.

Nun exportiere ich alle "Lld. Nr." in eine Textdatei.

Jetzt möchte ich bei einer anderen Datenbank diese txt Datei einlesen.
Wie zerlege ich aber nun jede Lfd. Nr. wieder in eine Variable an der ich dann Filtern kann?

Komm einfach nicht drauf.

Vielen Dank für Eure Hilfe!

Hallo kannst du mir vl. ein Beispiel der Textdatei posten damit ich verstehe wie du "zerlegen" meinst?

LG

Im Prinzip so:

Code:

8;
11;
16;
29;
37;
46;
57;
66;
80;
91;
97;
111;
120;
134;
143;

Trennzeichen ist aber Beeinflussbar. Es sind ungefähr 2.600 Nummern.

Er soll mir jetzt überall bei Sachposten den Konto-AZ auf True stellen wo eben die Lfd.Nr. in der Textdatei steht.

Hallo,

probiers mal so

Code:

OBJECT Dataport 50000 Import G/L Entry Bool Flag
{
  OBJECT-PROPERTIES
  {
    Datum=11.08.08;
    Zeit=11:45:59;
    Ge„ndert=Ja;
    Versions Liste=;
  }
  PROPERTIES
  {
    Import=Ja;
    FieldStartDelimiter=<None>;
    FieldEndDelimiter=<None>;
    FieldSeparator=[;];
  }
  DATAITEMS
  {
    { PROPERTIES
      {
        DataItemTable=Table17;
        AutoSave=Nein;
        AutoUpdate=Nein;
        AutoReplace=Nein;
        DataItemTableView=SORTING(Lfd. Nr.)
                          ORDER(Ascending);
        OnBeforeImportRecord=BEGIN
                               CLEAR(EntryNo);
                             END;

        OnAfterImportRecord=BEGIN
                              IF GLEntry.GET(EntryNo) THEN BEGIN
                                GLEntry."Konto-AZ" := TRUE;
                                GLEntry.MODIFY();
                              END;
                            END;

      }
      FIELDS
      {
        {      ;     ;EntryNo              }
      }
       }
  }
  REQUESTFORM
  {
    PROPERTIES
    {
      Width=9020;
      Height=3410;
    }
    CONTROLS
    {
    }
  }
  CODE
  {
    VAR
      GLEntry : Record 17;
      EntryNo : Integer;

    BEGIN
    END.
  }
}


im grunde importierst du die Textdatei in die Variable "EntryNo" und im trigger OnAfterImportRecord holst du dir den Sachposten setzt dein Feld auf TRUE das wars eigentlich!
Bitte vorher in Testdatenbank ausprobieren!!!!

Ich hoffe ich habe deine anforderung richtig verstanden

LG

Hat alles Ohne Probleme funktioniert!

Vielen Dank für die schnelle Hilfe!