NAV 2013 R2 Interaktive Sortierung in einer Page

Bild Microsoft Dynamics NAV 2013 (aka "NAV 7")

NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon MichaelK » 24. Juli 2014 16:28

Hallo,

kann es sein, dass in NAV 2013 R2 die interaktive Sortierung in einer Page bei Flowfields nicht funktioniert?

GruĂź

Michael
MichaelK
Microsoft Partner
Microsoft Partner
 
Beiträge: 550
Registriert: 4. März 2009 10:21
Realer Name: Michael Kaluza
Arbeitsort: Lustenau
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 3.70,4.00,5,2009,2013,2015

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon Natalie » 24. Juli 2014 19:11

Wie genau meinst du das?
GruĂź, Natalie

Frage beantwortet oder Problem von allein gelöst? Schreibe bitte [Gelöst] vor den Titel des ersten Beitrags.

Bitte erst suchen, dann fragen. Bitte beachte den kleinen Community-Knigge.
Kein Support per PN, Mail, IM oder Telefon! DafĂĽr ist dieses Forum da.
Benutzeravatar
Natalie
Moderator
Moderator
 
Beiträge: 9257
Registriert: 31. Oktober 2006 19:51
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon Kowa » 24. Juli 2014 22:28

Nach Flowfields geht nicht (die können ja auch nicht Teil eines normalen festen Schüssels sein)
http://msdn.microsoft.com/en-us/library/hh179484(v=nav.71).aspx
GruĂź, Kai

Frage beantwortet? Schreibe bitte [Gelöst] vor den Titel des ersten Beitrags.
Bitte erst suchen, dann fragen. Bitte beachte den kleinen Community-Knigge.
Kein Support per PN, Mail, Messenger oder Telefon! DafĂĽr ist dieses Forum da.

Download: Dynamics NAV Object Text Explorer (Alternativlink). MVP Alumni
Benutzeravatar
Kowa
Moderator
Moderator
 
Beiträge: 7835
Registriert: 17. Juni 2005 17:32
Wohnort: Bremen
Realer Name: Kai Kowalewski
Arbeitsort: Osterholz-Scharmbeck
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics 365
Microsoft Dynamics Version: BC, NAV 2018 bis Navision 2.01

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon MichaelK » 25. Juli 2014 13:02

Hallo,

wenn ich in einer ListPage auf ein Flowfield klicke um die Liste zu sortieren:

Feld.jpg


Field50001.jpg


dann bekomme ich folgende Fehlermeldung:

Microsoft Dynamics NAV
---------------------------

Die angegebene Spalten-ID '50001' wurde in der Abfrage nicht gefunden.

Die Seite 'Katalogartikel' muss geschlossen werden.
---------------------------
OK
---------------------------


Kommt diese Fehlermeldung, weil ich nicht nach Flowfields sortieren kann?

GruĂź

Michael
Field50001.jpg
MichaelK
Microsoft Partner
Microsoft Partner
 
Beiträge: 550
Registriert: 4. März 2009 10:21
Realer Name: Michael Kaluza
Arbeitsort: Lustenau
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 3.70,4.00,5,2009,2013,2015

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon Fido » 2. August 2014 17:39

Hallo,
also bei mir geht das, sowohl in einer Listpage, alsauch in einem Repeater einer Document Page. Auch unabhängig davon, ob ich einen "Count" als Flowfield definiert habe oder einen "SUM" .

Welchen Stand hast du eingesetzt (Build) und noch eine Anmerkung:
Setze bitte das kalkulierte Feld auf "Editable"= No.

LG Micha
Fido
Microsoft Partner
Microsoft Partner
 
Beiträge: 180
Registriert: 19. April 2007 09:48
Wohnort: Pleinfeld
Realer Name: Michael Kral
Arbeitsort: NĂĽrnberg
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 2.60..2017

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon MichaelK » 4. August 2014 12:32

Hallo Fido,

wir setzten die 37221 Buildversion ein.

GruĂź

Michael
MichaelK
Microsoft Partner
Microsoft Partner
 
Beiträge: 550
Registriert: 4. März 2009 10:21
Realer Name: Michael Kaluza
Arbeitsort: Lustenau
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 3.70,4.00,5,2009,2013,2015

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon SilverX » 4. August 2014 15:56

Also ich kann nach FlowFields beliebig sortieren und auch die Sicht speichern. Filtern zusätzlich funktioniert auch. Builds 7.1.37221 und 7.1.37563.

Beispielsweise Reservierte Menge in der Verkaufszeile oder auch Lagerbestand (hinzugefĂĽgt) in der ArtikelĂĽbersicht.
Die Fehlermeldung deutet meiner Meinung nach eher auf ein anderes generelleres Problem hin...
Cheers
Carsten


This post is my own opinion and does not necessarily reflect the opinion or view of my employer.
SilverX
Microsoft Partner
Microsoft Partner
 
Beiträge: 1252
Registriert: 16. September 2006 14:07
Realer Name: Carsten Scholling
Arbeitsort: GĂĽtersloh
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 2013+

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon Fido » 4. August 2014 16:02

Hallo ,
der Meinung bin ich auch (also der von Carsten). Kompiliere mal alle beteiligten Objekte durch und irgendwie , ich weiß jetzt auch net, kommt mir die erste Zeile der Tabelle mit den 922 Einträgen komisch vor, also die Katalogartikel, die wohl keinem Kreditor zugeordnet sind.
Kannst du mal das komplette Calc-Formular zur VerfĂĽgung stellen?

MFG
Micha
Fido
Microsoft Partner
Microsoft Partner
 
Beiträge: 180
Registriert: 19. April 2007 09:48
Wohnort: Pleinfeld
Realer Name: Michael Kral
Arbeitsort: NĂĽrnberg
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 2.60..2017

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon MichaelK » 5. August 2014 15:01

Hallo,

hier ist der Code von der Tabelle:

Code: Alles auswählen
OBJECT Table 5718 Nonstock Item
{
  OBJECT-PROPERTIES
  {
    Date=07.09.12;
    Time=12:00:00;
    Version List=NAVW17.00,042;
  }
  PROPERTIES
  {
    OnInsert=BEGIN
               NonStockItem.LOCKTABLE;
               IF "Entry No." = '' THEN BEGIN
                 GetInvtSetup;
                 InvtSetup.TESTFIELD("Nonstock Item Nos.");
                 NoSeriesMgt.InitSeries(InvtSetup."Nonstock Item Nos.",xRec."No. Series",0D,"Entry No.","No. Series");
               END;
             END;

    OnModify=BEGIN
               "Last Date Modified" := TODAY;
               MfrLength := STRLEN("Manufacturer Code");
               VenLength := STRLEN("Vendor Item No.");

               NonStockItemSetup.GET;
               CASE NonStockItemSetup."No. Format" OF
                 NonStockItemSetup."No. Format"::"Entry No.":
                   ItemNo := "Entry No.";
                 NonStockItemSetup."No. Format"::"Vendor Item No.":
                   ItemNo := "Vendor Item No.";
                 NonStockItemSetup."No. Format"::"Mfr. + Vendor Item No.":
                   IF NonStockItemSetup."No. Format Separator" = '' THEN BEGIN
                     IF MfrLength + VenLength <= 20 THEN
                       ItemNo := INSSTR("Manufacturer Code","Vendor Item No.",6)
                     ELSE
                       ItemNo := INSSTR("Manufacturer Code","Entry No.",6);
                   END ELSE BEGIN
                     TempItemNo :=
                       INSSTR("Manufacturer Code",NonStockItemSetup."No. Format Separator",6);
                     IF MfrLength + VenLength < 20 THEN
                       ItemNo := INSSTR(TempItemNo,"Vendor Item No.",7)
                     ELSE
                       ItemNo := INSSTR(TempItemNo,"Entry No.",7);
                   END;
                 NonStockItemSetup."No. Format"::"Vendor Item No. + Mfr.":
                   IF NonStockItemSetup."No. Format Separator" = '' THEN BEGIN
                     IF VenLength + MfrLength <= 20 THEN
                       ItemNo := INSSTR("Vendor Item No.","Manufacturer Code",11)
                     ELSE
                       ItemNo := INSSTR("Entry No.","Manufacturer Code",11);
                   END ELSE BEGIN
                     TempItemNo :=
                       INSSTR("Vendor Item No.",NonStockItemSetup."No. Format Separator",10);
                     IF VenLength + MfrLength < 20 THEN
                       ItemNo := INSSTR(TempItemNo,"Manufacturer Code",11);
                   END;
               END;
               Item.SETRANGE("No.",ItemNo);
               // Start 001.MH
               IF NOT NoCheckItem THEN
               // Stop 001.MH
               IF Item.FINDFIRST THEN
                 ERROR(Text001);
             END;

    CaptionML=[DEU=Katalogartikel;
               ENU=Nonstock Item;
               DEA=Katalogartikel];
    LookupPageID=Page5726;
    DrillDownPageID=Page5726;
  }
  FIELDS
  {
    { 1   ;   ;Entry No.           ;Code20        ;OnValidate=BEGIN
                                                                IF "Entry No." <> xRec."Entry No." THEN BEGIN
                                                                  GetInvtSetup;
                                                                  NoSeriesMgt.TestManual(InvtSetup."Nonstock Item Nos.");
                                                                  "No. Series" := '';
                                                                END;
                                                              END;

                                                   CaptionML=[DEU=Lfd. Nr.;
                                                              ENU=Entry No.;
                                                              DEA=Lfd. Nr.];
                                                   Editable=Yes }
    { 2   ;   ;Manufacturer Code   ;Code10        ;TableRelation=Manufacturer.Code;
                                                   OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Manufacturer Code" <> xRec."Manufacturer Code") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Herstellercode;
                                                              ENU=Manufacturer Code;
                                                              DEA=Herstellercode] }
    { 3   ;   ;Vendor No.          ;Code20        ;TableRelation=Vendor.No.;
                                                   OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Vendor No." <> xRec."Vendor No.") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);

                                                                IF "Vendor No." <> xRec."Vendor No." THEN
                                                                  IF CheckVendorItemNo("Vendor No.","Vendor Item No.") THEN
                                                                    ERROR(Text002,"Vendor No.","Vendor Item No.");
                                                              END;

                                                   CaptionML=[DEU=Kreditorennr.;
                                                              ENU=Vendor No.;
                                                              DEA=Kreditorennr.] }
    { 4   ;   ;Vendor Item No.     ;Code20        ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Vendor Item No." <> xRec."Vendor Item No.") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);

                                                                IF "Vendor Item No." <> xRec."Vendor Item No." THEN
                                                                  IF CheckVendorItemNo("Vendor No.","Vendor Item No.") THEN
                                                                    ERROR(Text002,"Vendor No.","Vendor Item No.");
                                                              END;

                                                   CaptionML=[DEU=Kred.-Artikelnr.;
                                                              ENU=Vendor Item No.;
                                                              DEA=Kred.-Artikelnr.] }
    { 5   ;   ;Description         ;Text50        ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF (Description <> xRec.Description) AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Beschreibung;
                                                              ENU=Description;
                                                              DEA=Beschreibung];
                                                   Editable=Yes }
    { 6   ;   ;Unit of Measure     ;Code10        ;TableRelation="Unit of Measure";
                                                   OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Unit of Measure" <> xRec."Unit of Measure") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Einheit;
                                                              ENU=Unit of Measure;
                                                              DEA=Einheit] }
    { 7   ;   ;Published Cost      ;Decimal       ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Published Cost" <> xRec."Published Cost") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Listen-EK-Preis;
                                                              ENU=Published Cost;
                                                              DEA=Listen-EK-Preis];
                                                   AutoFormatType=1 }
    { 8   ;   ;Negotiated Cost     ;Decimal       ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Negotiated Cost" <> xRec."Negotiated Cost") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Vereinbarter EK-Preis;
                                                              ENU=Negotiated Cost;
                                                              DEA=Vereinbarter EK-Preis];
                                                   AutoFormatType=1 }
    { 9   ;   ;Unit Price          ;Decimal       ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Unit Price" <> xRec."Unit Price") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=VK-Preis;
                                                              ENU=Unit Price;
                                                              DEA=VK-Preis];
                                                   AutoFormatType=1 }
    { 10  ;   ;Gross Weight        ;Decimal       ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Gross Weight" <> xRec."Gross Weight") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Bruttogewicht;
                                                              ENU=Gross Weight;
                                                              DEA=Bruttogewicht];
                                                   DecimalPlaces=0:5 }
    { 11  ;   ;Net Weight          ;Decimal       ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Net Weight" <> xRec."Net Weight") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Nettogewicht;
                                                              ENU=Net Weight;
                                                              DEA=Nettogewicht];
                                                   DecimalPlaces=0:5 }
    { 12  ;   ;Item Category Code  ;Code10        ;TableRelation="Item Category";
                                                   OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Item Category Code" <> xRec."Item Category Code") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);

                                                                "Product Group Code" := '';
                                                              END;

                                                   CaptionML=[DEU=Artikelkategoriencode;
                                                              ENU=Item Category Code;
                                                              DEA=Artikelkategoriencode] }
    { 13  ;   ;Product Group Code  ;Code10        ;TableRelation="Product Group".Code WHERE (Item Category Code=FIELD(Item Category Code));
                                                   OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Product Group Code" <> xRec."Product Group Code") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Produktgruppencode;
                                                              ENU=Product Group Code;
                                                              DEA=Produktgruppencode] }
    { 14  ;   ;Last Date Modified  ;Date          ;CaptionML=[DEU=Korrigiert am;
                                                              ENU=Last Date Modified;
                                                              DEA=Korrigiert am];
                                                   Editable=No }
    { 15  ;   ;Bar Code            ;Code20        ;OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Bar Code" <> xRec."Bar Code") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Barcode;
                                                              ENU=Bar Code;
                                                              DEA=Barcode] }
    { 16  ;   ;Item No.            ;Code20        ;TableRelation=Item.No.;
                                                   OnValidate=BEGIN
                                                                // Start 001.MH
                                                                IF NOT NoCheckItem THEN
                                                                // Stop 001.MH
                                                                IF ("Item No." <> xRec."Item No.") AND
                                                                   ("Item No." <> '')
                                                                THEN
                                                                  ERROR(Text001);
                                                              END;

                                                   CaptionML=[DEU=Artikelnr.;
                                                              ENU=Item No.;
                                                              DEA=Artikelnr.];
                                                   Editable=No }
    { 53  ;   ;Comment             ;Boolean       ;FieldClass=FlowField;
                                                   CalcFormula=Exist("Comment Line" WHERE (Table Name=CONST(Nonstock Item),
                                                                                           No.=FIELD(Entry No.)));
                                                   CaptionML=[DEU=Bemerkung;
                                                              ENU=Comment;
                                                              DEA=Bemerkung];
                                                   Editable=No }
    { 97  ;   ;No. Series          ;Code10        ;TableRelation="No. Series";
                                                   CaptionML=[DEU=Nummernserie;
                                                              ENU=No. Series;
                                                              DEA=Nummernserie];
                                                   Editable=No }
    { 50000;  ;Prefix              ;Text1         ;CaptionML=[ENU=Prefix;
                                                              DEA=Pr„fix] }
    { 50001;  ;Item Count          ;Integer       ;FieldClass=FlowField;
                                                   CalcFormula=Count(Item WHERE (Vendor No.=FIELD(Vendor No.),
                                                                                 Vendor Item No.=FIELD(Vendor Item No.)));
                                                   CaptionML=[ENU=Item Count;
                                                              DEA=Anzahl Artikel] }
    { 50002;  ;Vendor Item Count   ;Integer       ;FieldClass=FlowField;
                                                   CalcFormula=Count("Item Vendor" WHERE (Vendor No.=FIELD(Vendor No.),
                                                                                          Vendor Item No.=FIELD(Vendor Item No.)));
                                                   CaptionML=[ENU=Number of Vendor Item Count;
                                                              DEA=Anzahl Lieferantenartikel] }
  }
  KEYS
  {
    {    ;Entry No.                               ;Clustered=Yes }
    {    ;Vendor Item No.,Manufacturer Code        }
    {    ;Item No.                                 }
    {    ;Vendor No.,Vendor Item No.               }
  }
  FIELDGROUPS
  {
  }
  CODE
  {
    VAR
      Text001@1001 : TextConst 'DEU=Bearbeitung nicht zul„ssig, da der Artikel bereits vorhanden ist.;ENU=Modification not allowed, item record already exists.;DEA=Bearbeitung nicht zul„ssig, da der Artikel bereits vorhanden ist.';
      NonStockItem@1002 : Record 5718;
      NonStockItemSetup@1003 : Record 5719;
      Item@1004 : Record 27;
      InvtSetup@1013 : Record 313;
      NoSeriesMgt@1011 : Codeunit 396;
      ItemNo@1005 : Code[20];
      TempItemNo@1006 : Code[20];
      MfrLength@1008 : Integer;
      VenLength@1009 : Integer;
      Text002@1010 : TextConst 'DEU="Nr.=<%1> und Kred.-Artikelnr.=<%2> sind bereits vorhanden.";ENU="No.=<%1> and Vendor Item No.=<%2> already exists.";DEA="Nr.=<%1> und Kred.-Artikelnr.=<%2> sind bereits vorhanden."';
      HasInvtSetup@1012 : Boolean;
      __@1000000000 : Integer;
      NoCheckItem@1000000001 : Boolean;

    PROCEDURE AssistEdit@2() : Boolean;
    BEGIN
      GetInvtSetup;
      InvtSetup.TESTFIELD("Nonstock Item Nos.");
      IF NoSeriesMgt.SelectSeries(InvtSetup."Nonstock Item Nos.",xRec."No. Series","No. Series") THEN BEGIN
        NoSeriesMgt.SetSeries("Entry No.");
        EXIT(TRUE);
      END;
    END;

    PROCEDURE CheckVendorItemNo@1(VendorNo@1000 : Code[20];VendorItemNo@1001 : Code[20]) : Boolean;
    BEGIN
      NonStockItem.RESET;
      NonStockItem.SETCURRENTKEY("Vendor No.","Vendor Item No.");
      NonStockItem.SETRANGE("Vendor No.",VendorNo);
      NonStockItem.SETRANGE("Vendor Item No.",VendorItemNo);
      EXIT(NonStockItem.FINDFIRST);
    END;

    PROCEDURE GetInvtSetup@14();
    BEGIN
      IF NOT HasInvtSetup THEN BEGIN
        InvtSetup.GET;
        HasInvtSetup := TRUE;
      END;
    END;

    PROCEDURE _F_@1000000001();
    BEGIN
    END;

    PROCEDURE SetNoCheckItem@1000000000(noCheckItemPar@1000000000 : Boolean);
    BEGIN
      // Start 001.MH
      NoCheckItem := noCheckItemPar;
      // Stop 001.MH
    END;

    PROCEDURE UpdatePrice@1000000002(startDatePar@1000000003 : Date;endDatePar@1000000004 : Date) : Boolean;
    VAR
      itemLoc@1000000002 : Record 27;
      purchPriceLoc@1000000001 : Record 7012;
      purchPrice2Loc@1000000000 : Record 7012;
      itemVendorLoc@1000000005 : Record 99;
    BEGIN
      // Start 001.MH
      IF "Item No." = '' THEN BEGIN
        IF ("Vendor No." <> '') AND
           ("Vendor Item No." <> '') THEN BEGIN
          CALCFIELDS("Item Count","Vendor Item Count");
          IF "Item Count" = 1 THEN BEGIN
            itemLoc.RESET;
            itemLoc.SETRANGE("Vendor No.","Vendor No.");
            itemLoc.SETRANGE("Vendor Item No.","Vendor Item No.");
            IF itemLoc.FINDFIRST THEN BEGIN
              "Item No." := itemLoc."No.";
              MODIFY;
            END;
          END;
          IF "Item Count" = 0 THEN BEGIN
            IF "Vendor Item Count" = 1 THEN
            BEGIN
              itemVendorLoc.RESET;
              itemVendorLoc.SETRANGE("Vendor No.","Vendor No.");
              itemVendorLoc.SETRANGE("Vendor Item No.","Vendor Item No.");
              IF itemVendorLoc.FINDFIRST THEN BEGIN
                "Item No." := itemVendorLoc."Item No.";
                MODIFY;
              END;
            END;
          END;

        END;
      END;
      IF "Item No." <> '' THEN BEGIN
        IF itemLoc.GET("Item No.") THEN BEGIN
          IF itemLoc."Vendor No." = "Vendor No." THEN
          BEGIN
            itemLoc.VALIDATE("Unit Price","Unit Price");
            itemLoc.MODIFY(TRUE);
          END;
          purchPriceLoc.RESET;
          purchPriceLoc.SETRANGE("Item No.","Item No.");
          purchPriceLoc.SETRANGE("Vendor No.","Vendor No.");
          purchPriceLoc.SETRANGE("Starting Date",startDatePar);
          purchPriceLoc.SETRANGE("Ending Date",endDatePar);
          IF purchPriceLoc.FINDFIRST THEN BEGIN
            purchPriceLoc.VALIDATE("Direct Unit Cost","Negotiated Cost");
            purchPriceLoc.MODIFY(TRUE);
          END ELSE BEGIN
            purchPriceLoc.RESET;
            purchPriceLoc.SETRANGE("Item No.","Item No.");
            purchPriceLoc.SETRANGE("Vendor No.","Vendor No.");
            purchPriceLoc.SETFILTER("Ending Date",'%1|>=%2',0D,startDatePar);
            IF purchPriceLoc.FINDSET(TRUE,TRUE) THEN BEGIN
              REPEAT
                IF purchPriceLoc."Starting Date" > startDatePar-1 THEN BEGIN
                  IF (endDatePar = 0D) OR
                     (purchPriceLoc."Ending Date" <= endDatePar) THEN BEGIN
                    purchPriceLoc.DELETE(TRUE);
                  END ELSE BEGIN
                    purchPrice2Loc.INIT;
                    purchPrice2Loc := purchPriceLoc;
                    purchPrice2Loc."Starting Date" := endDatePar + 1;
                    purchPriceLoc.DELETE(TRUE);
                    purchPrice2Loc.INSERT(TRUE);
                  END;
                END ELSE BEGIN
                  purchPriceLoc.VALIDATE("Ending Date",startDatePar-1);
                  purchPriceLoc.MODIFY(TRUE);
                END;
              UNTIL purchPriceLoc.NEXT = 0;
            END;
            purchPriceLoc.INIT;
            purchPriceLoc.VALIDATE("Item No.","Item No.");
            purchPriceLoc.VALIDATE("Vendor No.","Vendor No.");
            purchPriceLoc.VALIDATE("Starting Date",startDatePar);
            purchPriceLoc.VALIDATE("Unit of Measure Code",itemLoc."Base Unit of Measure");
            purchPriceLoc.VALIDATE("Direct Unit Cost","Negotiated Cost");
            purchPriceLoc.VALIDATE("Ending Date",endDatePar);
            IF NOT purchPriceLoc.INSERT(TRUE) THEN BEGIN
              purchPriceLoc.MODIFY(TRUE);
            END;
          END;
          EXIT(TRUE);
        END;
      END;
      EXIT(FALSE);
      // Stop 001.MH
    END;

    BEGIN
    {
    }
    END.
  }
}


und hier von der Page:

Code: Alles auswählen
OBJECT Page 90000 Test
{
  OBJECT-PROPERTIES
  {
    Date=05.08.14;
    Time=14:54:20;
    Modified=Yes;
    Version List=;
  }
  PROPERTIES
  {
    SourceTable=Table5718;
    PageType=List;
  }
  CONTROLS
  {
    { 1000000000;0;Container;
                ContainerType=ContentArea }

    { 1000000001;1;Group  ;
                Name=Group;
                GroupType=Repeater }

    { 1000000002;2;Field  ;
                SourceExpr="Entry No." }

    { 1000000003;2;Field  ;
                SourceExpr="Manufacturer Code" }

    { 1000000004;2;Field  ;
                SourceExpr="Vendor No." }

    { 1000000005;2;Field  ;
                SourceExpr="Item Count" }

  }
  CODE
  {

    BEGIN
    END.
  }
}
MichaelK
Microsoft Partner
Microsoft Partner
 
Beiträge: 550
Registriert: 4. März 2009 10:21
Realer Name: Michael Kaluza
Arbeitsort: Lustenau
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 3.70,4.00,5,2009,2013,2015

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon SilverX » 6. August 2014 10:43

Hallo Michael,

ich kann/muss bestätigen, dass ich das Problem unter dem aktuellsten Build auch habe.

Während ich hier die Fehlermeldung bekomme, kann ich FlowFields auf die Tabelle Reservation Entry einwandfrei sortieren:
Code: Alles auswählen
Count("Reservation Entry" WHERE (Item No.=FIELD(Item No.)))
. Mir ist derzeit der Zusammenhang schleierhaft. Kannst du dazu bitte einen Fall bei uns einstellen?
Cheers
Carsten


This post is my own opinion and does not necessarily reflect the opinion or view of my employer.
SilverX
Microsoft Partner
Microsoft Partner
 
Beiträge: 1252
Registriert: 16. September 2006 14:07
Realer Name: Carsten Scholling
Arbeitsort: GĂĽtersloh
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 2013+

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon MichaelK » 6. August 2014 10:47

Hallo Carsten,

das habe ich bereits gemacht und bin auch sehr gespannt, was genau das Problem hier ist.

GruĂź

Michael
MichaelK
Microsoft Partner
Microsoft Partner
 
Beiträge: 550
Registriert: 4. März 2009 10:21
Realer Name: Michael Kaluza
Arbeitsort: Lustenau
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 3.70,4.00,5,2009,2013,2015

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon Fido » 8. August 2014 19:14

So meine Lieben,
des Rätsel Lösung ist die unterschiedliche Definition des Feldes "Vendor Item No." in den beiden beteiligten Tabellen.

Während man in Villa Riba (Tabelle 5718) noch von einem Code 20 spricht,
geht man in Villa Bacho (Tabelle 99) von einem Text 20 aus.

So wie ich den SQL-Server kenne, ist der ĂĽber diesen Umstand etwas ungehalten, da er sich hier ja SchlĂĽssel zur Sortierung aufbaut (zur Laufzeit) und wir ja wissen, das Text nicht gleich Code ist und umgekehrt.
Also nach dem Motto, wenn ich bei der Hausnr. 5 klingele (code-Feld) macht der von Hausnr. 5 (Text Feld) nicht auf.

Ich hab dann mal in der 99 ein neues Feld Code 20 "Item Vendor No. as Code" angelegt und die "Item Vendor No." da reingeschrieben. Im CalcFormula der Tabelle 5718 habe ich dann dieses Feld verwendet. ---- Schon klappt's mit dem Nachbarn (also Hausnr. 5); der hat aufgemacht. :lol:

Fazit: Die in dem CalcFormula verwendeten Feldtypen mĂĽssen gleich sein.

Jetzt kann man drüber streiten, ob das ein Fehler im Standard ist, aber das wäre eine andere Geschichte.

Beste GrĂĽĂźe
Micha
Fido
Microsoft Partner
Microsoft Partner
 
Beiträge: 180
Registriert: 19. April 2007 09:48
Wohnort: Pleinfeld
Realer Name: Michael Kral
Arbeitsort: NĂĽrnberg
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 2.60..2017

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon MichaelK » 11. August 2014 15:30

Hallo Fido,

Microsoft ist Dir sehr dankbar dafĂĽr, dass Du dies herausgefunden hast. Sie werden es als eine Korrektur fĂĽr eine der kommenden NAV Versionen planen.

Vielen Dank fĂĽr Deine Hilfe.

GruĂź

Michael
MichaelK
Microsoft Partner
Microsoft Partner
 
Beiträge: 550
Registriert: 4. März 2009 10:21
Realer Name: Michael Kaluza
Arbeitsort: Lustenau
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 3.70,4.00,5,2009,2013,2015

Re: NAV 2013 R2 Interaktive Sortierung in einer Page

Beitragvon Fido » 11. August 2014 15:34

O. K.
Alle klar,
man hilft doch gern wo man kann.
Danke fĂĽr die Info
GruĂź
Micha
Fido
Microsoft Partner
Microsoft Partner
 
Beiträge: 180
Registriert: 19. April 2007 09:48
Wohnort: Pleinfeld
Realer Name: Michael Kral
Arbeitsort: NĂĽrnberg
Bezug zu Microsoft Dynamics: Microsoft Partner
Microsoft Dynamics Produkt: Microsoft Dynamics NAV
Microsoft Dynamics Version: 2.60..2017


ZurĂĽck zu NAV 2013

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast